Avec WordArt, vous pouvez créer des effets de texte décoratifs, par exemple le texte ombré ou en miroir. À l’aide d’un programme VBA, un aperçu des 30 différents types d’effets est généré ci-dessous. La méthode AddTextEffect () est utilisée pour cela. Le résultat est à nouveau un objet de la classe Shape.
Sub CreationWordArt()
Dim sh As Shape
Dim i As Integer, lf As Integer, tp As Integer
' Sélectionnez la feuille de calcul
ThisWorkbook.Worksheets("Feuil5").Activate
' Pas de grille
ActiveWindow.DisplayGridlines = False
' À vider
For i = ActiveSheet.Shapes().Count To 1 Step -1
ActiveSheet.Shapes(i).Delete
Next i
' Valeurs de départ
lf = 5
tp = 5
' Tous les différents préréglages WordArt
For i = 0 To 29
Set sh = ActiveSheet.Shapes().AddTextEffect( _
i, i, "Arial", 48, False, False, lf, tp)
sh.TextFrame.Characters.Font.Color = _
RGB(255, 0, 0)
' Position suivante
lf = lf + 70
If i Mod 6 = 5 Then
lf = 10
tp = tp + 70
End If
Next i
End Sub
Commentaires
■ Comme dans le programme précédent, les lignes de la grille sont masquées et toutes les formes existantes sont supprimées.
■ Après avoir défini la position de départ, la méthode AddTextEffect () est appelée dans la boucle. Il comporte huit paramètres obligatoires:
– Type d’effet de texte prédéfini,
– Texte affiché,
– Nom de la police,
– Taille de la police,
– gras oui / non,
– Italique oui / non,
– Position à gauche,
– Informations de position ci-dessus
■ La couleur de la police, c’est-à-dire la couleur du texte affiché dans le cadre de texte de la forme, est définie sur rouge.
■ À la fin de la boucle, la position de l’objet suivant est déterminée.
L’effet de texte peut être modifié davantage via les paramètres. La figure suivante montre une petite section.
Remarque
Les formulaires WordArt sont formés différemment dans les versions antérieures à Excel 2007. Pour cette raison, la propriété Color de l’objet police (pour afficher le numéro de série dans le formulaire) ne peut pas être définie. Les formes WordArt sont également différentes.