Comme vous le savez, les diagrammes peuvent être créés sur vos propres feuilles dans un classeur ou incorporés dans une feuille de calcul. Les deux méthodes sont présentées dans cette section. Le point de départ doit être un tableau avec des valeurs de température dans les deux cas:

Figure:  Exemple de données pour les diagrammes

1 Créer une feuille de graphique
Les graphiques sur leurs propres feuilles (feuilles de graphique) sont au même niveau dans la hiérarchie des objets que les feuilles de calcul. Il existe différentes listes dans un classeur:
■ Sheets contient toutes les feuilles de calcul et les feuilles de diagramme.

■ Worksheets ne contiennent que les feuilles de calcul.

■ Charts contient uniquement les feuilles de diagramme.
La procédure suivante crée un graphique linéaire simple en tant que feuille de graphique dans le classeur:

Sub CreerGraphFeuil()
ThisWorkbook.Charts.Add After:=Worksheets("Feuil1")
With ActiveChart
.ChartType = xlLine
.SetSourceData Worksheets("Feuil1").Range("A1:C8")
.Name = "Diagramm1"
End With
End Sub

Le résultat est illustré à la figure suivante.

Commentaires:
Afin d’expliquer:
■ La méthode Add () de l’objet Charts crée une feuille de graphique et l’ajoute à la liste de graphiques du classeur actif. Comme pour la copie ou le déplacement de feuilles de calcul, vous pouvez utiliser Avant et Après pour spécifier l’emplacement de la nouvelle feuille. S’il n’est pas spécifié, la nouvelle feuille est insérée avant la feuille actuellement active.
■ La nouvelle feuille de diagramme est de type Chart. Il devient la feuille de diagramme active. Par conséquent, il peut être résolu avec ActiveChart.
■ La propriété ChartType définit le type du diagramme, ici xlLine pour un diagramme linéaire. Certains types de graphiques importants sont répertoriés ci-dessous.
■ La méthode SetSourceData () définit la source de données du diagramme. Dans ce cas, il s’agit de la plage A1 à C8 de la feuille de tableau (avec les données de température).
■ Vous pouvez donner un nom au diagramme à l’aide de la propriété Name.

Remarque
La méthode SetSourceData () a un deuxième paramètre facultatif. Cela détermine si le diagramme affiche la table par colonnes (xlColumns) ou (xlRows). La première valeur est la norme.

Le tableau 1 présente certains types de diagrammes.

2 Créer un diagramme intégré
Les diagrammes incorporés se trouvent dans la hiérarchie d’objets sous les feuilles de calcul. La liste Worksheets contient la sous-liste ChartObjects, c’est-à-dire tous les cadres de graphique de la feuille de calcul. Un ChartObject est un élément de cette collection ChartObjects, c’est-à-dire un seul cadre de graphique.
Un diagramme unique est un objet de type Chart et représente la valeur de la propriété Chart d’un cadre de diagramme. À l’exception de cette classification, les deux formes de diagramme sont identiques. La procédure suivante incorpore un graphique linéaire simple dans la feuille Sheet1:

Sub CreerGraphIntegre()
Dim CO As ChartObject
Dim CH As Chart
Set CO = ThisWorkbook.Worksheets("Feuil1"). _
ChartObjects.Add(200, 10, 300, 150)
Set CH = CO.Chart
CH.ChartType = xlLine
CH.SetSourceData Worksheets("Feuil1"). _
Range("A1:C8")
End Sub

Figure 3 Diagramme intégré

Commentaires:
■ Tout d’abord, une variable de type ChartObject est déclarée. Il fait ensuite référence au cadre de diagramme nouvellement créé.
■ Une variable de type Chart est alors déclarée. Il se réfère plus tard au diagramme du cadre de diagramme nouvellement créé.
■ La liste ChartObjects contient tous les cadres des diagrammes incorporés dans une feuille de calcul. La méthode Add () crée un nouveau cadre de graphique à un emplacement et une taille spécifiques. Il renvoie une référence à l’objet nouvellement créé. Les quatre paramètres de Add () représentent:
– Distance du cadre au bord gauche de la feuille de calcul
– Distance du cadre au bord supérieur de la feuille de calcul
– Largeur du cadre
– Hauteur du cadre
■ La propriété Chart de ChartObject représente le diagramme réel dans le cadre.
■ La propriété ChartType est déjà connue; il définit le type du diagramme.
■ La méthode SetSourceData () est également déjà connue. Il définit la source de données du diagramme. Dans ce cas, il s’agit de la zone A1 à C8 de la feuille de calcul active.