Un graphique à secteurs doit servir d’exemple supplémentaire pour un graphique nouvellement créé, incorporé et formaté. Vous pouvez voir que de nombreuses propriétés générales du diagramme peuvent être extraites du diagramme linéaire. Cependant, d’autres propriétés existent uniquement avec les graphiques à secteurs. Le tableau suivant sert de sources de données:
Sub DiagrammeFormatage()
Dim CO As ChartObject
Dim CH As Chart
Dim i As Integer
Set CO = ThisWorkbook.Worksheets("Feuil1"). _
ChartObjects.Add(200, 10, 400, 350)
Set CH = CO.Chart
' Type de graphique et source de données
CH.ChartType = xlPie
CH.SetSourceData Range("A1:B13")
' Diagramme et zone de dessin
CH.ChartArea.Interior.Color = vbCyan
CH.PlotArea.Interior.Color = vbYellow
' Titre
CH.HasTitle = True
CH.ChartTitle.Text = "Valeur total"
' Légende
CH.HasLegend = True
With CH.Legend
.Interior.Color = vbYellow
.Border.Color = vbBlue
.Border.Weight = xlThick
End With
'Points de données
CH.SeriesCollection(1).Points(1). _
Interior.Color = vbWhite
For i = 1 To CH.SeriesCollection(1).Points.Count
If Cells(i + 1, 2) > 200 Then
With CH.SeriesCollection(1).Points(i)
.ApplyDataLabels _
xlDataLabelsShowLabelAndPercent
.DataLabel.NumberFormat = "0.00 %"
End With
End If
Next i
End Sub
Commentaires
■ Comme on le sait, le cadre du graphique est nouvellement créé avec ChartObject.Add ().
■ xlPie est utilisé comme type de diagramme, pour les diagrammes à secteurs (diagrammes circulaire).
■ Le diagramme et la zone de dessin, le titre et la légende peuvent être formatés comme le diagramme linéaire.
■ Cela semble différent avec la série de données. Il n’y a bien sûr aucun marquage, mais:
– Avec xlDataLabelsShowLabelAndPercent un type d’étiquette spécial et
– une surface intérieure.
■ Dans le cas présent, le type d’étiquette est utilisé pour étiqueter les points de données dont la valeur est supérieure à une limite avec une catégorie et un pourcentage.
■ La surface intérieure d’un point de données est également représentée en blanc.
■ La propriété DataLabel détermine l’apparence de l’étiquette DataLabel. Ici, il a été déterminé que le pourcentage devrait être affiché avec deux décimales.